        DEFB 0FEH       ; Программа запускается с адреса &H9000
        DEFW START,KONEC+END-NACH,START
        ORG  09000H

CLS     EQU 00C3H       ; Очистка экрана
KEYOFF  EQU CLS+09H     ; Отключение функциональных клавиш
FORCLR  EQU 0F3E9H      ; Адрес цвета изображения
COLOR   EQU 0062H       ; Установка цвета
CONSOL  EQU 00A2H       ; Вывод символа на консоль.

START:  LD   HL,PROM    ; Адрес старта реставрируемой подпрограммы 
        PUSH HL         ; Сохранили в стеке и при встрече RET
        DI              ; переходим на этот адрес.
        LD   A,0A8H     ; Организация страниц RАМ и ROM:
        LD   (0FFFFH),A ; 0 страница (0000H-4000H)-BASIC (BIOS)
        LD   A,0FCH     ; 1 страница (4000H-8000H)-СЛОТB 3-2
        OUT  (0A8H),A   ; 2 страница (8000H-C000H)-СЛОТB 3-2
        LD   HL,KONEC+1 ; 3 страница (C000H-FFFFH)-СЛОТB 3-2
        LD   DE,NACH    ; Пересылка подпрограммы на начало 
        LD   BC,END-NACH; первой страницы слота 3-2
        LDIR            ;
KONEC:  RET             ;
                        ;
        ORG  04000H     ;
                        ;
NACH:   DEFM "AB"       ; Идентификатор псевдо-ROM
        DEFW PROM       ; Адрес старта подпрограммы
        DEFS 12         ; Зарезервировано стандартом
PROM:   XOR  A          ;
        CALL CLS        ;
        CALL KEYOFF     ; Установка цвета,CLS и KEYOFF
        LD   HL,FORCLR  ; CLS:KEYOFF:COLOR 15,9,9
        LD   (HL),0FH   ;
        INC  HL         ;
        LD   (HL),09H   ;
        INC  HL         ;
        LD   (HL),09H   ;
        CALL COLOR      ;
        CALL INLINE     ; Печать строки на мониторе
;       ...               Здесь может размещаться Ваша программа.
;       ...               Она будет работать даже при отключении
LABEL:  JP   LABEL      ; компьютера с помощью кнопки "RESET"

INLINE: LD   HL,STROKA  ; Подпрограмма вывода символов на консоль
        LD   A,(HL)     ;
        LD   C,A        ;
        OR   A          ;
        RET  Z          ;
        LD   A,C        ;
        PUSH HL         ;
        CALL CONSOL     ;
        POP  HL         ;
        INC  HL         ;
        JR   INLINE+3   ;

STROKA: DEFM "ВЫКЛЮЧИ КОМПЬЮТЕР НА МИНУТУ."
        NOP
END:    NOP
